@problem@
	@problemtype@
		embedded
	@;problemtype@
	@name@
		tutorial_7_global_configuration
	@endname@
	@preamble@
		y = randval([3,5])
	@;preamble@
	@config@
		roundednote = false
		keepfloat = true
		debug = true
	@;config@
	@content@
		There are multiple ways of setting global configuration options: First, you can edit the file "MECK.cfg" in the "config" folder of MECK. All configuration options are listed and explained in this file. In particular, you can set the input and ouput folder for problem files and compiled xml files, respectively, in this file.
		@pb;@
		Next, you can specify options in the command line when executing MECK. For example if you want to compile the file named "problem.xmu" in the input folder, then running MECK with the command line arguments "--debug=True problem.xmu" will compile the problem file in debug mode.
		@pb;@
		Finally, you can set configuration options directly in the problem or exam description files (cf. Tutorial A0). Note that in the above 'config' block, we have set the option 'roundednote' to 'false', which means that by default, numerical answers will no longer be marked as requiring rounded input:
		@lb;@
		If the square of x is equal to 2 and x is positive, then @numericalans(100,sqrt(2))@.
		@pb;@
		Note that in this case, the option can be overridden by using the named argument 'roundedNote"':
		@lb;@
		If the square of x is equal to @y@ and x is positive, then @numericalans(100,sqrt(y),roundedNote=True)@.
		@pb;@
		Similarly, the line "keepfloat = true" in the 'config' block sets the default representation of floating point numbers to a decimal representation instead of a fraction. In particular, the expression of a value itself (e.g. y+0.5 = @y+0.5@) will be changed accordingly, as will the default representation via the 'num' function (e.g. y+0.5 = @num(y+0.5)@).
		@pb;@
		Please refer to the command reference for a brief description of the available configuration options.
	@;content@
@;problem@